１．サンプル †

コンテキストメニューへのコマンドボタンの作成方法は前章のコマンドメニューとほとんど同じです。 コマンドメニューが作成したコマンドバーにControを追加するのに対して、コンテキストメニューの場合Applicationの既存のコマンドバーにControlを追加します。
パラメータ、ショートカットキーの設定、FaceID、既存のコマンドボタンの設定などは前章を参照して下さい。
以下のサンプルでは、Cellのコンテキストメニューに対してボタンを追加しています。

Sub Context_Create()
    Dim myCBCtrl As CommandBarButton
 
    Set myCBCtrl = Application.CommandBars("Cell").Controls.Add(Before:=1)
    With myCBCtrl
        .Caption = "太文字(&B)"
        .FaceID = 113
        .OnAction = "Bold_Set"
    End With

    Set myCBCtrl = Application.CommandBars("Cell").Controls.Add(Before:=2)
    With myCBCtrl
        .Caption = "レ(&L)"
        .FaceID = 1087
        .OnAction = "Check_Input"
        .BeginGroup = True
    End With

    Application.CommandBars("Cell").Controls.Add Type:=msoControlButton, ID:=2640, Before:=3

    '以下ではドロップダウンリストを作成しています。
    With Application.CommandBars("Cell").Controls.Add(Type:=msoControlPopup, Before:=4)
            .Caption = "背景"
             With .Controls.Add(Type:=msoControlButton)
                .Caption = "赤"
                .FaceID = 7492
                .OnAction = "Interior_Red(&R)"
            End With
           With .Controls.Add(Type:=msoControlButton)
                .Caption = "水色"
                .FaceID = 6855
                .OnAction = "Interior_SkyBlue(&S)"
            End With
    
            With .Controls.Add(Type:=msoControlButton)
                .Caption = "黄"
                .FaceID = 7491
                .OnAction = "Interior_Yellow(&Y)"
            End With
    End With

End Sub

コンテキストメニューが残ったままにならないように、コンテキストメニューを初期状態に戻すプロシージャをWorkbookを閉じる前に必ず実行させます。コンテキストメニューの場合、既存のコンテキストメニューを削除しないようにメソッドはDeleteではなくResetを使用します。

Sub Context_Reset()
    
    Application.CommandBars("Cell").Reset

End Sub

またワークブックの各イベントに以下のような処理を追加します。

Private Sub Workbook_Open()

    Context_Create

End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
   
   Context_Reset

End Sub